home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / clipper / nannws13.zip / CLIPMEM.PRG next >
Text File  |  1987-05-22  |  6KB  |  209 lines
  1. * CLIPMEM.PRG
  2. * 
  3. * Date:   February 1987
  4. * Author: David Morgan
  5. * Notes:  Simulates Clipper Autumn '86 memory allocation
  6. *          groundrules explained in Nantucket News, Autumn
  7. *          1986, p. 4.
  8. *         Requires DOS 3.x or greater for assembly routines
  9. * 
  10. * Input:  configuration information about machine environment
  11. *          as follows --
  12. *
  13. *         tot_conv = amount of conventional memory installed (K)
  14. *         tot_exp  = amount of expanded memory installed
  15. *         dos_size = size of DOS as loaded at runtime
  16. *         load_module = size of your application's load module
  17. *         CLIPPER  = copy of the runtime CLIPPER environment
  18. *                    string
  19. *
  20. * Output: memory allocation/distribution information as follows
  21. *
  22. *         X         = amt of mem excluded
  23. *         mem_vars  = amt of mem devoted to storing memvars
  24. *         run_space = amt of mem for RUNning/perhaps indexing
  25. *         pool      = amt of memory devoted to free pool
  26. *         exp_space = amt of expanded mem. devoted to indexing
  27. *                     if zero, indexing shares run_space
  28. *                     otherwise run_space is for exclusive use
  29. *                     by RUN commands
  30. *
  31.  
  32. PARAMETERS tot_conv,tot_exp,dos_size,load_module
  33. param_count = PCOUNT()
  34. CLEAR
  35. CLIPPER=UPPER(GETE('CLIPPER')+' ')
  36. numerals = '1234567890'
  37. params = 'VREX'
  38. error = .F.
  39. DO CASE
  40.  CASE param_count=0    && get parameters from this machine
  41.   tot_conv = MEM_AMT()  
  42.   tot_conv = 16 * iif(tot_conv<0,65536+tot_conv,tot_conv) / 1024
  43.   tot_conv = (INT(tot_conv+.5))
  44.   tot_exp = 16*EM_AMT()
  45.   dos_size = 16*DOS_SIZ()/1024
  46.   dos_size = (INT(dos_size+.5))
  47.   load_module = 0
  48.   @ 6,0
  49.   TEXT
  50.   CLIPMEM will read remaining memory configuration parameters
  51.    from this machine.
  52.  
  53.  
  54.   Alternative calling syntax you may use to specify parameters
  55.    yourself, reflecting any machine:
  56.  
  57.   CLIPMEM tot_conv tot_exp dos_size load_module
  58.   ENDTEXT
  59.   @ 4,0 SAY 'What is the load module size? ' GET load_module;
  60.    RANGE 100,600
  61.   READ
  62.  CASE param_count=4    && take parameters from command line
  63.   tot_conv=VAL(tot_conv)
  64.   tot_exp=VAL(tot_exp)
  65.   dos_size=VAL(dos_size)
  66.   load_module =VAL(load_module)
  67.  OTHERWISE
  68.   DO TERMINATE
  69. ENDCASE
  70.  
  71. * range checking
  72. DO CASE
  73.  CASE tot_conv<256 .OR. tot_conv>640
  74.   error = .T.
  75.  CASE tot_exp<0 .OR. tot_exp>8192
  76.   error = .T.
  77.  CASE dos_size<20 .OR. dos_size>200
  78.   error = .T.
  79.  CASE load_module<100 .OR. load_module>600
  80.   error = .T.
  81. ENDCASE
  82. IF error
  83.  DO TERMINATE
  84. ENDIF
  85.  
  86. * analyze CLIPPER string
  87. p2 = 1
  88. DO WHILE p2 <= 4
  89.  curr_par = SUBSTR(params, p2, 1)
  90.  error = .F.
  91.  IF AT('&curr_par',CLIPPER)>0
  92.   p1 = AT('&curr_par',CLIPPER)+1
  93.   no_chars = 0
  94.   DO WHILE SUBSTR(CLIPPER,P1,1)$numerals
  95.    no_chars = no_chars + 1
  96.    p1 = p1 + 1
  97.   ENDDO
  98.   error = IIF(no_chars=0, .T., .F.)
  99.   IF .NOT.error
  100.    &curr_par = VAL(SUBSTR(CLIPPER,p1-no_chars,no_chars))
  101.   ELSE
  102.    CLEAR
  103.    ? 'Error in CLIPPER string format. Calculation canceled.'
  104.    CANCEL
  105.   ENDIF
  106.  ELSE
  107.   &curr_par=0
  108.  ENDIF
  109.  p2 = p2 + 1
  110. ENDDO :p2<=4
  111.  
  112. * follow the groundrules to calculate each memory category
  113. left_over = tot_conv - dos_size - load_module
  114. excluded = X
  115. left_over = left_over - excluded
  116. pool=24
  117. left_over = left_over - pool
  118. mem_vars = IIF(V>0,V,IIF( .2*left_over > 44 , 44, .2*left_over))
  119. left_over = left_over - mem_vars
  120. run_space = IIF(R > 0 ,  R, left_over/3 )
  121. run_space = IIF(tot_exp=0.AND.run_space < 16, 16, run_space)
  122. left_over = left_over - run_space
  123. pool = pool + left_over
  124.  
  125. IF AT('E',CLIPPER) > 0               && 'E' param present
  126.  IF E=0
  127.   exp_space = 0
  128.  ELSE
  129.   exp_space = E                       && E specified, but
  130. * can't exceed 1MB:
  131.   exp_space = IIF(exp_space>1024, 1024, exp_space)
  132. * or EMM total:
  133.   exp_space = IIF(exp_space>tot_exp, tot_exp, exp_space)
  134. * need 16K at least:
  135.   exp_space = IIF(exp_space<16, 0, exp_space)
  136.  ENDIF
  137. ELSE                            && no 'E' param
  138.  exp_space = IIF(tot_exp>1024, 1024, tot_exp)   && gets all EMM
  139.  exp_space = IIF(exp_space<16, 0, exp_space)    && up to 1MB
  140. ENDIF
  141.  
  142. IF mem_vars<=0.OR.pool<=0
  143.  DO TERMINATE
  144. ENDIF
  145. * print results
  146. CLEAR
  147. ? "Approximate Memory Distribution for Clipper Autumn '86"
  148. ?
  149. ? 'Configuration:'
  150. ? ' Installed conventional memory:  '+STR(tot_conv)
  151. ? ' Installed expanded memory:      '+STR(tot_exp)
  152. ? ' DOS memory consumption:         '+STR(dos_size)
  153. ? ' Application memory consumption: '+STR(load_module)
  154. ? ' CLIPPER environment string:     '
  155. IF ' '=CLIPPER
  156.  ?? 'NONE'
  157. ELSE
  158.  ?? CLIPPER
  159. ENDIF
  160. ?
  161. ? 'Conventional Memory:'
  162. ? SUBSTR(' DOS'+SPACE(20),1,20)+STR(dos_size)
  163. ? SUBSTR(' Application module'+SPACE(20),1,20)+STR(load_module)
  164. ? SUBSTR(' Excluded'+SPACE(20),1,20)+STR(X)
  165. ? SUBSTR(' Memory variables'+SPACE(20),1,20);
  166.    +STR(INT(mem_vars+.5))
  167. IF exp_space > 0
  168.  ? SUBSTR(' RUN'+SPACE(20),1,20)+STR(INT(run_space+.5))
  169. ELSE
  170.  ? SUBSTR(' RUN+Indexing'+SPACE(20),1,20)+STR(INT(run_space+.5))
  171. ENDIF
  172. ? SUBSTR(' Free pool'+SPACE(20),1,20)+STR(INT(pool+.5))
  173. ?
  174. ? 'Expanded Memory:'
  175. ? SUBSTR(' Indexing'+SPACE(20),1,20)+STR(exp_space)
  176. ?
  177. ? '>>> All values approximate <<<'
  178. @ 22,0
  179. QUIT
  180.  
  181.  
  182. PROCEDURE TERMINATE
  183. CLEAR
  184. ?? CHR(7)
  185. TEXT
  186.  Error occurred.  Calling syntax is either:
  187.  
  188.    CLIPMEM tot_conv tot_exp dos_size load_module    (no commas)
  189.  
  190.                     or
  191.    CLIPMEM
  192.  
  193. You must supply either 4 or 0 command line parameters. If you do not
  194. supply them they are read internally from the current machine or 
  195. you are prompted for them. The current CLIPPER string is read from memory.
  196. Requires DOS 3.x or greater. Calculated values must be positive.
  197.  
  198. Significance of parameters:                              Allowed Range
  199.  
  200. tot_conv = amount of conventional memory installed (K)     256 -  640
  201. tot_exp  = amount of expanded memory installed               0 - 8192
  202. dos_size = size of DOS as loaded at runtime                 20 -  200
  203. load_module = size of your application's load module       100 -  600
  204. CLIPPER  = copy of the runtime CLIPPER environment string
  205. ENDTEXT
  206. @ 22,0
  207. QUIT
  208. RETURN
  209.